sandbox-maxima-worked-example-3

Before we get started, load ezunits.

load (ezunits);

/usr/local/share/maxima/branch_5_32_base_2_g0e99686/share/ezunits/ezunits.mac

1 Units in integrals and derivatives

1.1 Integral

Units for integrals and derivatives are derived as the same units that a finite approximation would yield. Turn off simplification for a moment so that we can have a look at the unsimplified form.

simp : false $
foo : 'integrate ((3 * t^2) ` m/s, t ` s, 0 ` s, t[1] ` s);

$${\int }_{0\mathrm{s}}^{t_1\mathrm{s}}3t^2\frac{\mathrm{m}}{\mathrm{s}}𝑑t\mathrm{s}$$

Now go ahead and simplify it.

simp : true $
foo : ''foo;

$$3\left({\int }_0^{t_1}{t}^2𝑑t\right)\mathrm{m}$$

%, nouns;

$$t_1^3\mathrm{m}$$

1.2 Derivative

Again, have a look at the unsimplified form.

simp : false $
foo : 'diff (sqrt (t) ` inch, t ` year, 1);

$$\frac{d{+}^1}{d{\mathrm{`}}^1(t,\mathrm{𝑦𝑒𝑎𝑟})}\left(\sqrt{t}\mathrm{inch}\right)$$

Go ahead and simplify it.

simp : true $
foo : ''foo;

$$\frac{d}{dt}\sqrt{t}\frac{\mathrm{inch}}{\mathrm{year}}$$

foo, nouns;

$$\frac{1}{2\sqrt{t}}\frac{\mathrm{inch}}{\mathrm{year}}$$

2 Units in solving equations

‘solve_dimensional’ can solve equations in which unit-ful expressions contain unknowns.

foo : solve_dimensional (10^6 ` Btu = 1/2 * (10 ` lbm) * v^2, v);

$$\left[v=\left(-{\mathrm{8\hspace{0.17em}5}}^{\frac{5}{2}}\right)\frac{\sqrt{\mathrm{Btu}}}{\sqrt{\mathrm{lbm}}},v={\mathrm{8\hspace{0.17em}5}}^{\frac{5}{2}}\frac{\sqrt{\mathrm{Btu}}}{\sqrt{\mathrm{lbm}}}\right]$$

dimensions (foo);

$$\left[\mathrm{𝑑𝑖𝑚𝑒𝑛𝑠𝑖𝑜𝑛𝑠}\left(v\right)=\frac{\mathrm{𝑙𝑒𝑛𝑔𝑡ℎ}}{\mathrm{𝑡𝑖𝑚𝑒}},\mathrm{𝑑𝑖𝑚𝑒𝑛𝑠𝑖𝑜𝑛𝑠}\left(v\right)=\frac{\mathrm{𝑙𝑒𝑛𝑔𝑡ℎ}}{\mathrm{𝑡𝑖𝑚𝑒}}\right]$$

foo1 : foo `` m/s;

$$\left[\mathrm{`}\mathrm{`}(v,\frac{m}{s})=\left(-\frac{{\mathrm{128\hspace{0.17em}5}}^{\frac{13}{2}}\sqrt{1055}}{\sqrt{45359237}}\right)\frac{\mathrm{m}}{\mathrm{s}},\mathrm{`}\mathrm{`}(v,\frac{m}{s})=\frac{{\mathrm{128\hspace{0.17em}5}}^{\frac{13}{2}}\sqrt{1055}}{\sqrt{45359237}}\frac{\mathrm{m}}{\mathrm{s}}\right]$$

float (foo1);

$$\left[\mathrm{`}\mathrm{`}(v,\frac{m}{s})=\left(-21567.92463845541\right)\frac{\mathrm{m}}{\mathrm{s}},\mathrm{`}\mathrm{`}(v,\frac{m}{s})=21567.92463845541\frac{\mathrm{m}}{\mathrm{s}}\right]$$

3 Selecting a named field from a unit-ful expression

‘@’ distributes over unit-ful expressions.

defstruct (my3d (x, y, z));

$$\left[\mathit{my3d}(x,y,z)\right]$$

foo : my3d (17, 29, 42) ` m;

$$\mathit{my3d}(17,29,42)\mathrm{m}$$

foo @ z;

$$\mathrm{@}(\mathit{my3d}(17,29,42),z)\mathrm{m}$$

Hmm, looks like it needs a little encouragement.

''%;

$$42\mathrm{m}$$

4 Real part and imaginary part of a unit-ful expression

Simplifications for unit-ful expressions apply only to noun forms of ‘realpart’ and ‘imagpart’. Oh well.

declare (a, complex) $
realpart (a ` m);

$$\mathrm{𝑟𝑒𝑎𝑙𝑝𝑎𝑟𝑡}\left(a\mathrm{m}\right)$$

''%;

$$\mathrm{𝑟𝑒𝑎𝑙𝑝𝑎𝑟𝑡}\left(a\right)\mathrm{m}$$

imagpart (a ` m);

$$\mathrm{𝑖𝑚𝑎𝑔𝑝𝑎𝑟𝑡}\left(a\mathrm{m}\right)$$

''%;

$$\mathrm{𝑖𝑚𝑎𝑔𝑝𝑎𝑟𝑡}\left(a\right)\mathrm{m}$$

5 Splitting off units of varying magnitudes

This one is for converting to units which come in conventional magnitude order, such as hours, minutes, and seconds, or miles, feet, and inches. When the units are specified as a list, the unit conversion operator will split off the first, then the second from the remainder of the first, the third from the remainder, etc.

10 ` km `` mile;

$$\frac{78125}{12573}\mathrm{mile}$$

10 ` km `` [mile, yard, foot, inch];

$$[6\mathrm{mile},376\mathrm{yard},0\mathrm{foot},\frac{608}{127}\mathrm{inch}]$$

apply ("+", %) `` km;

$$10\mathrm{km}$$

Title	sandbox-maxima-worked-example-3
Canonical name	Sandboxmaximaworkedexample3
Date of creation	2014-12-30 17:48:15
Last modified on	2014-12-30 17:48:15
Owner	robert_dodier (1000903)
Last modified by	robert_dodier (1000903)
Numerical id	1
Author	robert_dodier (1000903)
Entry type	Example